Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section 1 - Decorar el pantano con las cosas que se pueden escuchar
[--------------------------------------------------
Algo de texto aleatorio, pero no solo,
una suerte de 'sonidos', cuando se
atiende hecho a mano
--------------------------------------------------]
Definition: a room is listenable if it is Pantano1 or it is Pantano23 or it is Pantano25.
Definition: a thing is listenable if it is a patroller or it is a cadaver.
Before listening to a direction:
say "Mejor escuchar en todas direcciones...";
try listening instead.
Before listening to a thing:
say "Intentas escuchar desde las proximidades [the noun].".
Instead of listening:
let algoEscuchado be false;
if there is a listenable adjacent room (called lugar):
let way be the best route from the location to lugar;
if lugar is:
-- Pantano1:
say "Desde [the way] llega el refrescante sonido de agua corriente.";
now algoEscuchado is true;
-- Pantano23:
say "Escuchas sonidos normales (y desagradables) del pantano, excepto desde [the way] en donde los animales parecen callar. Que extraño...";
now algoEscuchado is true;
-- Pantano25:
say "Extraños sonidos, como si el viento zarandease las plantas llegan desde [the way], pero... no hay viento.";
now algoEscuchado is true;
otherwise if there is a listenable thing (called cosa) in an adjacent room (called lugar):
let way be the best route from the location to lugar;
if cosa is a cadaver:
say "Un considerable ruido de insectos llegan desde [the way], como si algo en descomposición los hubiese atraído.";
now algoEscuchado is true;
otherwise:
if cosa is:
-- deavork:
say "En [the way] se escucha como si algo zarandease las plantas.";
now algoEscuchado is true;
-- lobo:
if hambre of lobo is greater than 40:
say "Desde [the way] llegan unos apagados quejidos lastimosos.";
now algoEscuchado is true;
-- zhur:
say "[one of]Escuchas desde [the way] unas apagadas palabras en lenguaje orco.[or]En [the way] se escuchan como chapoteos.[or]Alguien parece andar por [the way].[at random]";
now algoEscuchado is true;
-- yerk:
say "[one of]Escuchas desde [the way] unas apagadas palabras en lenguaje orco.[or]En [the way] el sonido de algo pesado y lento moviéndose.[or]Alguien parece andar por [the way], ¿un elefante tal vez?.[at random]";
now algoEscuchado is true;
-- berg:
say "[one of]Escuchas desde [the way] unas apagadas palabras en lenguaje orco.[or]En [the way] el sonido una risilla bastante molesta.[or]Alguien parece andar por [the way]... no, no, ha sido sólo una impresión.[at random]";
now algoEscuchado is true;
-- icalante:
if icalante is enfadado:
say "Desde [the way] llegan extraños gruñidos.";
now algoEscuchado is true;
if algoEscuchado is false:
if location is Copa:
say "Algo de viento se cuela entre las hojas de este enorme árbol. Abajo en el pantano se escuchan los sonidos de los anfibios y los insectos.";
otherwise if location is PuertaCastillo:
say "En este lugar el sonido del eterno fuego del foso de brea de la fortaleza cubre a cualquier otro ruido que pueda haber.";
otherwise if location is Pantano28:
say "Extraños sonidos escapan del túnel que lleva a los sótanos de la fortaleza.";
otherwise if location is Cueva1:
say "Aquí el silencio es el rey, al menos en comparación con el pantano.";
otherwise if location is Lava:
say "El ruido que hace la lava al avanzar lentamente, los gases borboteando pesadamente, el crujir de las rocas, cubre cualquier otro sonido.";
otherwise if location is Lugar Oo Drack:
say "Un extraño temblor casi imperceptible se puede 'notar', más que oirse. ¿Qué será?.";
otherwise if location is parte del pantano:
say "[one of]Se escuchan ranas, pero eso no impide que se escuchen moscas y cosas así.[or]Moscas, mosquitos, más moscas, más mosquitos.[or]Pues... ya sabes, los ruidos típicos del pantano: criaturas lamentables lamentándose de ser lamentables.[at random]";
otherwise if location is cueva oscura:
say "Grietas, grietas y más grietas. Túneles horadados por la colonia de deavorks y cosas probablemente más sucias. ¡Se puede ir en cualquier dirección! Todas parecen igual de improbables y desagradables.";
otherwise:
say "No hay mucho que escuchar más allá de tus propios pasos.".